Les exemples
SI avec ET et OU
SI imbriqué
RECHERECHEV avec MOIS
RECHERCHEV avec JOURSEM
RECHERCHEV pour trimestre
TROUVE et SIERREUR
TROUVE, SIERREUR et STXT
Le plus grand avantage d’Excel n’est pas de savoir comment utiliser les 476 fonctions actuellement disponibles, mais bien comment les utiliser ensemble; de les imbriquer. La prochaine section vous montre quelques exemples.
Avant de commencer, il faut comprendre qu’une fonction se termine toujours par la fin d’une parenthèse soit « ) ». Ex. : =somme(B5 :B25) , =SI(B2 = "Grossiste"; C2 * 10%; 0)
Les fonctions imbriquées sont toujours placées dans l’un des paramètres de la première fonction. Une fonction imbriquée ne se retrouve jamais entre deux paramètres. Pour les prochains exemples, j’ai écrit la fonction imbriquée en rouge afin que vous puissiez plus facilement l’identifier.
Le premier exemple est l’un que plusieurs d’entre vous ont déjà vu ou appliqué. Il s’agit de combiner la fonction SI avec la fonction ET ou OU. À titre de rappel, la fonction SI requiert trois paramètres, aussi appelés « arguments », afin d’avoir un résultat. La formulation est SI(condition; action si vrai; action si faux). La condition requiert aussi trois éléments : un élément à comparer, un opérateur logique et un autre élément à comparer. Voici quelques exemples :
B2 = "Grossiste"
C2 >= 100000
B3 = 2025-10-31
B4=VRAI
moyenne(B5 :B25)>75
somme(B5 :B25)>somme(C5 :C25)
Ces exemples montrent des combinaisons possibles avec des adresses de cellules, des formules et des références à du texte, une date ou un binaire (VRAI).
La condition nous permet de déterminer le seuil que la première valeur doit atteindre pour que le résultat soit vrai. Sinon, le résultat de la condition sera faux. Cela va permettre à la fonction de pointer vers l’action si vraie ou l’action si fausse.
La limitation de la condition de la fonction SI est qu’elle permet de vérifier qu’un seul élément. Il arrive fréquemment qu’il faille comparer plusieurs conditions en même temps. C’est à ce moment qu’il est nécessaire d’utiliser la fonction ET ou la fonction OU. Celles-ci permettent de vérifier plusieurs conditions en même temps.
ET(condition 1; condition 2 …) OU(condition 1; condition 2 …)
Le « ; » sert à séparer les conditions. Vous pouvez avoir un maximum de 255 conditions.
ET(B2 = "Grossiste"; C2 >= 100000)
OU(B2 = "Grossiste"; C2 >= 100000)
Pour que le résultat de la fonction ET soit vrai, toutes les conditions doivent être vrais. Le résultat sera faux si juste une condition est fausse. Le résultat de la fonction OU sera vrai si juste l’une des conditions est vraie. Le résultat de la fonction OU sera faux si tous les résultats des conditions sont faux.
Pour tirer avantage de ses fonctions, il faut l’implanter ou l’imbriquer dans la fonction SI à la place de la condition. SI(ET(condition1; condition 2 …); action si vraie, action si fausse). Comme dans cet exemple, la fonction ET est à l’intérieur de la fonction SI dans le paramètre de la condition. On peut réaliser la même chose en utilisant la fonction ou : SI(OU(condition1; condition 2 …); action si vrai, action si faux). Voici deux exemples.
=SI(ET(B2="Grossiste";C2>=100000);C2 * 10%;0)
Dans cette formule, on calcule 10% du contenu de la cellule C2 si son contenu est supérieur à 100 000 ET que le contenu de la cellule B2 = « Grossiste ». Sinon, le résultat est de 0.
=SI(OU(B2="Grossiste";C2>=100000);C2 * 10%;0)
Cette formule calcule 10% du contenu de la cellule C2 si la valeur est supérieure à 100 000 OU que le contenu de la cellule B2 = « Grossiste ». Sinon, le résultat est de 0. On vérifie si l’une ou l’autre des conditions a été remplie.
C’est la situation qui va déterminer si vous devez valider plusieurs conditions en même temps et si celles-ci doivent être tout être réalisés au même moment ou juste l’une d’entre elles.
Les nouveaux usagers à l’option d’imbriquer des fonctions éprouvent deux difficultés. La première est la maitrise des fonctions qu’ils désirent utiliser. La deuxième est de savoir où imbriquer une fonction dans une autre. La fonction imbriquée doit toujours être placée au complet à l’intérieur des paramètres de la première fonction.
Un autre exemple est d’imbriquer la fonction SI à l’intérieur d’une autre fonction SI. Ceci est nécessaire lorsque vous devez valider une condition avant d’en valider une autre. Cette seconde fonction SI se retrouvera donc soit dans le paramètre « action si vraie » ou « action si fausse ». Voici deux exemples.
SI(B2="Grossiste";SI(C2>=100000;C2*10%;0);0)
On vérifie initialement si le contenu de B2 est « Grossiste ». Si vrai, on vérifie si C2 est supérieur ou égal à 100 000. Si c’est vrai à cette seconde condition, on calcule 10% de C2. Si le résultat est faux pour l’une ou l’autre des conditions, le résultat sera de 0.
SI(B2="Grossiste";C2*10%;SI(C2>=100000;C2*10%;0))
Ces deux dernières formules sont l’équivalent des formules SI(ET et SI(OU que vous avez vus dans les exemples précédents. Cependant, les conditions ont été réalisées l’un après l’autre au lieu d’être validées en même temps. Il y a des moments ou vous pouvez, et devez, tester plusieurs conditions en même temps en utilisant les fonctions ET ou OU. À d’autres moments, il est requis de valider une condition avant de valider une autre. C’est dans ce dernier cas qu’imbriquer la fonction SI à l’intérieur d’un autre est nécessaire.
En analytique, il est souvent nécessaire d’extraire des données d’un certain format pour le convertir en un autre. C’est pour cela qu’Excel offre plusieurs fonctions de conversion en format de texte, de chiffre, de date et d’heure parmi d’autres.
Voici une série de dates. Il faut afficher à côté le nom du mois. Si la liste est courte, vous pourriez le réaliser manuellement. Cela n’est pas pratique si vous avez des centaines, voir des milliers, de dates à convertir. Voici comment créer une formule qui combine les fonctions MOIS et RECHERCHEV pour afficher le nom du mois pour cette liste de dates.
La fonction MOIS(date) va extraire le numéro du mois de la date recherchée. Le résultat sera toujours un chiffre entre 1 (pour janvier) et 12 (pour décembre). Votre directeur ne veut pas le résultat des ventes selon le numéro du mois mais selon son nom. Il faut donc convertir ce chiffre en un texte qui représente le nom du mois. C’est à ce moment que la fonction RECHERCHEV avec un tableau de comparaison sera pratique.
=MOIS(2025-10-31) = 10 soit le 10ième mois de l’année
À titre de rappel, la fonction RECHERCHEV requiert un minimum de trois paramètres. Un quatrième paramètre est optionnel.
RECHERCHEV(Valeur à comparer; Tableau de comparaison; Index colonne;[Valeur approximatif])
Excel utilise les caractères [ ] pour indiquer qu’un paramètre est optionnel. Comme mentionné, il faudra créer un tableau de comparaison avant de pouvoir utiliser la fonction RECHERCHEV.
Voici le tableau de comparaison qui sera utilisé pour cet exercice. Il sera placé de F1 à G12. Le contenu de la première colonne sera utilisé pour comparer avec le numéro du mois. La seconde colonne sera utilisée pour afficher le nom du mois.
Placez dans la cellule B1 la formule suivante : =RECHERCHEV(MOIS(A1);F$1:G$12;2)
N’oubliez pas qu’il faut ficher les références des lignes, avec le signe $ devant le numéro de ligne, puisque vous allez recopier cette formule aux cellules B2 à B5. Vous ne voulez pas que le tableau de comparaison soit décalé chaque fois que vous recopiez la formule.
Recopiez la formule en B1 aux cellules B2 jusqu’à B5.
Le prochain exemple démontre une approche similaire pour le nom du jour au lieu du nom du mois. Vous devrez combiner la fonction RECHERCHEV avec la fonction JOURSEM. Cette fonction donne comme résultat le numéro du jour entre 1 (pour dimanche) et 7 (pour samedi).
=JOURSEM(2025-10-31) = 6 soit un vendredi
Encore une fois, votre directeur ne désire pas analyser la performance de la semaine en utilisant les numéros pour représenter les jours. Il faut donc convertir ces chiffres en journées.
Il faut un tableau de comparaison afin de pouvoir utiliser la fonction RECHERCHEV.
Dans la cellule C1, entrez la formule suivante : =RECHERCHEV(JOURSEM(A1);J$1:K$7;2) .
Cette formule qui imbrique la fonction JOURSEM dans le premier paramètre de la fonction RECHERCHEV affiche le nom du jour comme demandé. Vous pouvez recopier cette formule aux autres dates.
Copiez la formule C1 aux cellules C2 à C5.
Une autre option qui est souvent demandée est de regrouper les mois en semestres ou en trimestres. Ajustons un tableau de comparaison précédent pour afficher le trimestre approprié.
Il y a deux façons d’écrire la prochaine formule qui ira dans la cellule D1.
=RECHERCHEV(MOIS(A1);F$1:H$12;3)
On utilise le tableau de comparaison avec le mois et on y ajoute une colonne pour identifier le trimestre. Au lieu d’affiche le contenu de la deuxième colonne du tableau de comparaison, la fonction va afficher le contenu de la troisième colonne qui indique le trimestre.
=RECHERCHEV(B1;G$1:H$12;2;FAUX)
L’alternative à cette formule est d’utiliser le nom du mois pour identifier le bon trimestre. Le tableau de comparaison change pour commencer à G1 où l’on retrouve le nom des mois. Il faut aussi ajouter le quatrième paramètre à FAUX pour indiquer que la fonction doit retrouver une valeur exacte. La fonction RECHERCHEV est plus souvent utilisée pour retrouver une valeur entre X et Y; une valeur approximative. Dans ce cas, il faut absolument retrouver le bon nom du mois. C’est pour cela qu’il faut ajouter le quatrième paramètre pour retrouver la valeur exacte.
Excel offre aussi plusieurs fonctions pour extraire du texte d’une cellule telles que GAUCHE, DROITE et STXT. La fonction TROUVE indique la position exacte d’un caractère ou d’un texte dans le contenu d’une cellule. Par exemple, on retrouve souvent le caractère « : » pour séparer l’heure des minutes comme 09:43 ou 15:45.
=TROUVE(":";"Vendredi 31 octobre 2025, 10:43" ) = 29 Le « : » est le 29ième caractère à partir de la gauche.
On peut facilement extraire les heures et les minutes en sachant l’emplacement exact du séparateur. La formule serait :
=TROUVE(":";A1 )
Le problème avec cette fonction est qu’elle retourne un message d’erreur si elle ne retrouve pas l’élément recherché. C’est à ce moment que combiner la fonction SIERREUR à la fonction TROUVE devient pratique.
SIERREUR(formule normale; action si erreur)
Cette fonctionne laisse la formule opérer normalement. On retrouve la formule dans le premier paramètre de la fonction. Cependant, on retrouve dans le second paramètre l’action que la fonction doit prendre au cas ou le résultat de la formule donne une erreur.
Pour cet exemple, la formule sera :
=SIERREUR(TROUVE(":";A1);"")
Dans ce cas, on laisse la fonction TROUVE retrouver la caractère « : » dans la cellule A1. Cependant, s’il y a une erreur, la fonction SIERREUR affichera un vide qui est représenté par deux guillemets collé ensemble (""). Il n’y aura pas de message d’erreur. Seulement un vide pour représenter que rien n’a été trouvé.
Entrez les textes suivants dans la cellule A1 et constatez le résultat.
3 décembre 2025, 9:43
Vendredi 31 octobre 2025, 10:43
ABC
Maintenant que vous savez où se trouve le séparateur entre les heures et les minutes, utilisons la fonction STXT pour extraire le texte demandé.
STXT(cellule ayant le texte; position où on commence l’extraction dans le texte; le nombre de caractères à extraire)
Exemples :
=STXT("Ceci est un exemple.";6;3) = est
=STXT("Ceci est un exemple.";13;7) =exemple
Vous voyez maintenant comment cette fonction peut extraire du texte d’un exemple. On aurait pu aussi faire référence à une cellule et extraire du texte du contenu dans la cellule.
Dans la cellule C1, entrez la formule suivante :
=SIERREUR(STXT(A1;TROUVE(":";A1)-2;2);"")
Dans la cellule D1, entrez la cellule suivante :
=SIERREUR(STXT(A1;TROUVE(":";A1)+1;2);"")
On utilise la fonction TROUVE à l’intérieur de la fonction STXT afin de savoir où se trouve le « : » qu’on recherche. La cellule en C1 permet d’extraire l’heure qui est les deux caractères devant le « : ». C’est pour cela qu’on utilise -2 pour la position devant le TROUVE. Pour les minutes, se sont les deux caractères immédiatement après le « : ». C’est pour cela qu’on ajoute +1 pour déterminer la position de départ pour extraire les minutes.
Ces deux dernières formules utilisent trois fonctions, SIERREUR, STXT et TROUVE pour trouver la réponse recherchée. STXT est imbriqué dans SIERREUR et TROUVE est imbriqué dans STXT. Créer des modèles ou analyser des masses de données requièrent que vous maîtriser comment utiliser plusieurs fonctions. On se retrouve souvent dans des situations complexes. Donc, il est normal de vous vous retrouver à combiner des fonctions pour retrouver le résultat recherché. Ces exemples ne sont qu’un point de départ. Apprenez comment utiliser le plus de fonctions possibles. Ensuite, regardez comment vous pouvez les combiner à d’autres fonctions pour créer des modèles plus réalistes et rendre vos analyses plus faciles.